Tutorial 4: Kreslení textu

Teorie:

Zavolat BeginPaint jako odpověď na WM_PAINT zprávu.
Zavolat GetDC jako odpověď na jiné zprávy.
Zavolat CreateDC pro vytvoření svého vlastního kontextu zařízení.

Získat handel ke kontextu zařízení pomocí BeginPaint.
Kreslit do klientské oblasti
Uvolnit handel ke kontextu zařízení pomocí EndPaint

Obsah:

.386
.model flat,stdcall
option casemap:none

WinMain proto :DWORD,:DWORD,:DWORD,:DWORD

include \masm32\include\windows.inc
include \masm32\include\user32.inc
includelib \masm32\lib\user32.lib
include \masm32\include\kernel32.inc
includelib \masm32\lib\kernel32.lib

.DATA
ClassName db "SimpleWinClass",0
AppName  db "Our First Window",0
OurText  db "Win32 assembly is great and easy!",0

.DATA?
hInstance HINSTANCE ?
CommandLine LPSTR ?

.CODE
start:
    invoke GetModuleHandle, NULL
    mov    hInstance,eax
    invoke GetCommandLine
    mov CommandLine,eax
    invoke WinMain, hInstance,NULL,CommandLine, SW_SHOWDEFAULT
    invoke ExitProcess,eax

WinMain proc hInst:HINSTANCE, hPrevInst:HINSTANCE, CmdLine:LPSTR, CmdShow:DWORD
    LOCAL wc:WNDCLASSEX
    LOCAL msg:MSG
    LOCAL hwnd:HWND
    mov   wc.cbSize,SIZEOF WNDCLASSEX
    mov   wc.style, CS_HREDRAW or CS_VREDRAW
    mov   wc.lpfnWndProc, OFFSET WndProc
    mov   wc.cbClsExtra,NULL
    mov   wc.cbWndExtra,NULL
    push  hInst
    pop   wc.hInstance
    mov   wc.hbrBackground,COLOR_WINDOW+1
    mov   wc.lpszMenuName,NULL
    mov   wc.lpszClassName,OFFSET ClassName
    invoke LoadIcon,NULL,IDI_APPLICATION
    mov   wc.hIcon,eax
    mov   wc.hIconSm,eax
    invoke LoadCursor,NULL,IDC_ARROW
    mov   wc.hCursor,eax
    invoke RegisterClassEx, addr wc
    invoke CreateWindowEx,NULL,ADDR ClassName,ADDR AppName,\
           WS_OVERLAPPEDWINDOW,CW_USEDEFAULT,\
           CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,NULL,NULL,\
           hInst,NULL
    mov   hwnd,eax
    invoke ShowWindow, hwnd,SW_SHOWNORMAL
    invoke UpdateWindow, hwnd
        .WHILE TRUE
                invoke GetMessage, ADDR msg,NULL,0,0
                .BREAK .IF (!eax)
                invoke TranslateMessage, ADDR msg
                invoke DispatchMessage, ADDR msg
        .ENDW
        mov     eax,msg.wParam
        ret
WinMain endp

WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
    LOCAL hdc:HDC
    LOCAL ps:PAINTSTRUCT
    LOCAL rect:RECT
    .IF uMsg==WM_DESTROY
        invoke PostQuitMessage,NULL
    .ELSEIF uMsg==WM_PAINT
        invoke BeginPaint,hWnd, ADDR ps
        mov    hdc,eax
        invoke GetClientRect,hWnd, ADDR rect
        invoke DrawText, hdc,ADDR OurText,-1, ADDR rect, \
                DT_SINGLELINE or DT_CENTER or DT_VCENTER
        invoke EndPaint,hWnd, ADDR ps
    .ELSE
        invoke DefWindowProc,hWnd,uMsg,wParam,lParam
        ret
    .ENDIF
    xor   eax, eax
    ret
WndProc endp
end start

Analysis:

    LOCAL hdc:HDC
    LOCAL ps:PAINTSTRUCT
    LOCAL rect:RECT

Toto jsou lokální proměnné, které používají GDI funkce v naší WM_PAINT části. hdc ukládá handel ke kontextu zařízení obdržený od funkce BeginPaint, ps je PAINTSTRUCT struktura. Většinou nepoužíváte hodnoty uložené v ps. Je předána BeginPaint funkci a Windows ji naplní vhodnými hodnotami. Vy poté předáte ps EndPaint funkci, když skončíte s kreslením do klientské oblasti. rect je RECT struktura definována takto:
 

RECT Struct
    left           LONG ?
    top           LONG ?
    right        LONG ?
    bottom    LONG ?
RECT ends

        invoke BeginPaint,hWnd, ADDR ps
        mov    hdc,eax
        invoke GetClientRect,hWnd, ADDR rect
        invoke DrawText, hdc,ADDR OurText,-1, ADDR rect, \
                DT_SINGLELINE or DT_CENTER or DT_VCENTER
        invoke EndPaint,hWnd, ADDR ps

Jako reakci na WM_PAINT zprávu voláte BeginPaint s handelem k oknu, do kterého chcete kreslit a neinicializovanou PAINTSTRUCT strukturu jako parametry. Po úspěšném zavolání obsahuje eax handle ke kontextu zařízení. Dále voláme GetClientRect, abychom získali rozměry klientské oblasti. Rozměry jsou vráceny v proměnné rect, kterou předáváme funkci DrawText jako jeden z jejich parametrů. DrawText syntaxe je:

DrawText proto hdc:HDC, lpString:DWORD, nCount:DWORD, lpRect:DWORD, uFormat:DWORD

DrawText je vyšší API funkce pro výstup textu. Stará se o některé detaily jako je zarovnání slov, centrování apod., aby jste se mohli zaměřit na řetězec, který chcete nakreslit. Její nižší (low-level) bratříček, TextOut, bude objektem našeho zkoumání příště :). DrawText zformátuje řetězec tak, aby se vešel do obdélníku. Použije současně zvolený font, barvu a pozadí (v kontextu zařízení) a nakreslí text. Vrací výšku textu v jednotkách zařízení, v našem případě v pixelech. Pojďme si prohlédnout její parametry:

hdc  Handle ke kontextu zařízení
lpString  Ukazatel na řetězec, který chcete nakreslit. Řetězec musí být ukončen nulou, jinak by jste museli udat jeho délku v dalším parametru, nCount.
nCount  Počet znaků řetězce pro výstup. Jestliže je řetězec ukončen nulou, nCount musí být -1. Jinak musí nCount obsahovat počet znaků řetězce, který chcete kreslit.
lpRect  Ukazatel na obdélník (struktura typu RECT) do které chcete řetězec nakreslit. Tento obdélník je také ořezávacím (clipping) obdélníkem což znamená, že nemůžete kreslit mimo něj.
uFormat Hodnota, která udává jak bude řetězec zobrazen v obdélníku. Používáme tří hodnot kombinované pomocí "or" operátoru:
• DT_SINGLELINE  Určuje jeden řádek textu.
• DT_CENTER  Centruje text horizontálně
• DT_VCENTER Centruje vertikálně. Musí být použít s DT_SINGLELINE.

• Voláme BeginPaint-EndPaint pár jako reakci na WM_PAINT zprávu.
• Uděláme cokoliv se nám líbí s klientskou oblastí mezi BeginPaint a EndPaint.
• Pokud chcete překreslit oblast vašeho okna jako reakci na jiné zprávy, máte dvě možnosti:
• Použijte GetDC-ReleaseDC pár a své kreslení udělejte mezi těmito funkcemi.
• Zavolejte InvalidateRect nebo UpdateWindow  aby jste učinili svou klientskou oblast neplatnou, čímž donutíte Windows aby vložilo do fronty zpráv WM_PAINT zprávu, na kterou bude reagovat vaše WM_PAINT část kódu.