ASM Community

;*-------------------------------------------*

; int CRC32(*buffer, sizeof(buffer)); 

; Calculates a 32 Bit Cyclic Redundancy Code

; over a buffer with length sizeof(buffer).

; Polynom: EDB88320h (Winzip)

; Doesn't need any table or precalculations.

; Speed: ~2.4 MB/s on a Intel PII 300

; (c) tE!

;*-------------------------------------------*

CRC32 proc uses ebx esi edi lpbuffer:DWORD, lsize:DWORD

	mov	esi, lpbuffer

	mov	ebx, lsize

	xor	ecx, ecx

	lea	eax, [ecx-1]

	mov	edi, 0EDB88320h

@@m1:	xor	edx, edx

	mov	dl, [esi]

	xor	dl, al

@@m2:	shr	edx, 1

	jnc	@@m3

	xor	edx, edi

@@m3:	inc	ecx

	and	cl, 7

	jnz	@@m2

	shr	eax, 8

	xor	eax, edx

	inc	esi

	dec	ebx

	jg	@@m1	

	not	eax

	RET

CRC32 endp

;*-------------------------------------------*

; void InitCRC(void);

; Precomputes a 256*4 CRC array for use with

; Crc32()

;*-------------------------------------------*

InitCrc32Tbl PROC USES ESI EDI EBX



lea edi,crctab + (255*4)

xor edx,edx

dec dl

std 





CalcTblValues:

mov eax,edx

mov ebx,0edb88320h  ; winzip polynominal

 

push 8  ;mov ecx,8

pop ecx

 

ReflectBitsCompute_Loop:

shr eax,1    

sbb esi,esi  

and esi,ebx 

xor eax,esi  

dec ecx

jz ReflectBitsCompute_Loop



stosd

 

dec edx

jns CalcTblValues







cld

ret

InitCrc32Tbl ENDP







;*-------------------------------------------*

; int FastCRC(*buffer, sizeof(buffer);

; Calculates a 32 Bit Cyclic Redundancy Code

; over a buffer with length sizeof(buffer),

; using a precomputed CRC table. InitCRC()

; must be called *once* before.

; Speed: ~7 MB/s on a Intel PII 300

;*-------------------------------------------*

Crc32 PROC USES ESI EDI lpData:DWORD,bLen:DWORD



mov esi,lpData 

lea edi,crctab 

mov ecx,bLen 



xor eax,eax 

dec eax



@@:

xor edx,edx

mov dl,byte ptr [esi] 

inc esi               

xor dl,al             



shr eax,8                       

xor eax,dword ptr [edi+(edx*4)] 



dec ecx 

jnz @B



not eax 

ret

Crc32 ENDP