ASM Community

.386

.model flat,stdcall

option casemap:none



include \masm32\include\windows.inc

include \masm32\iinclude\user32.inc

include \masm32\iinclude\kernel32.inc



includelib \masm32\lib\user32.lib

includelib \masm32\lib\kernel32.lib



.const

NewLine	db 0Ah, 0Dh



.code



start proc uses esi edi



LOCAL hHeap:HANDLE

LOCAL pHeap:LPVOID

LOCAL cb:UINT



	invoke GetProcessHeap

	.if eax != NULL

		mov hHeap, eax

		; lets start with 1024 bytes

		mov cb, 1024

		invoke HeapAlloc, hHeap, 0, cb

		.if eax != NULL

			mov pHeap, eax



			.while TRUE

				invoke QueryDosDevice, NULL, pHeap, cb

				.if eax != 0

					; Process buffer filled with the info

					mov eax, cb

					add eax, 512

					invoke HeapAlloc, hHeap, HEAP_ZERO_MEMORY, eax

					.break .if eax == NULL

					mov edi, eax

					mov esi, pHeap



					.while TRUE

						invoke lstrcat, edi, esi

						invoke lstrcat, edi, addr NewLine

					

						invoke lstrlen, esi

						add esi, eax

						inc esi

						.break .if byte ptr [esi] == 0

					.endw



					invoke MessageBox, NULL, edi, NULL, MB_OK

					invoke HeapFree, hHeap, 0, edi

					.break

				.else

					invoke GetLastError

					.break .if eax != ERROR_INSUFFICIENT_BUFFER

					; assume 65536 byte is enough

					.break .if cb >= 1000h * 10h

					; try twice more memory

					shl cb, 1

					invoke HeapReAlloc, hHeap, 0, pHeap, cb

					.break .if eax == NULL

					mov pHeap, eax

				.endif

			.endw

		.endif



		invoke HeapFree, hHeap, 0, pHeap

	.endif



	invoke ExitProcess, 0	

	

start endp



end start