ASM Community

Try something like this

.386

.model flat, stdcall

option casemap :none   ; case sensitive



include \masm32\include\windows.inc

include \masm32\include\user32.inc

include \masm32\include\kernel32.inc

include \masm32\include\wininet.inc

includelib \masm32\lib\user32.lib

includelib \masm32\lib\wininet.lib

includelib \masm32\lib\kernel32.lib



.data

  url db "http://www.gmx.de",0

  useragent db "wininet_test",0

  hresult dd 0

  hopen HANDLE ?

  hfile HANDLE ?



.data?

      szStuff db 500 dup(?)





.code

start:

  invoke InternetOpen, ADDR useragent, INTERNET_OPEN_TYPE_DIRECT, NULL, NULL, 0

  mov hopen, eax

  invoke InternetOpenUrl, hopen, ADDR url, NULL, 0, INTERNET_FLAG_RELOAD, 0

  mov hfile, eax

  invoke InternetReadFile, hfile, offset szStuff, 500, offset hresult

  invoke InternetCloseHandle, hfile

  invoke InternetCloseHandle, hopen

  invoke MessageBox, NULL, offset szStuff, ADDR url, MB_OK

  invoke ExitProcess, 0

end start

This worked for me. I believe you are passing a handle where it is expecting the address of memory.

Hopefully this works for you,
gorshing

GlobalAlloc with GPTR should work just as you describe. Post a small bit of code with the problem. :)

Heh, I don't know .... InternetReadFile returns FALSE, GetLastError returned 87 == ERROR_INVALID_PARAMETER, MSDN says "The parameter is incorrect."

I'm trying to figure out what's wrong with the parameters.

The memory location returned by GlobalAlloc, it's ok to pass it like it is correct? We don't need to do the offset/addr on the variable correct? That's the only thing I can see.

Ohhh, it's your result variable!! You have

invoke InternetReadFile, hfile, hmem, 500, hresult

It needs to be

invoke InternetReadFile, hfile, hmem, 500, offset hresult

On MSDN

BOOL WINAPI InternetReadFile(

IN HINTERNET hFile, 

IN LPVOID lpBuffer, 

IN DWORD dwNumberOfBytesToRead, 

OUT LPDWORD lpdwNumberOfBytesRead

);

Hope this helps man,
gorshing